Author Topic: OpenGL: molehill  (Read 3684 times)

0 Members and 1 Guest are viewing this topic.

Offline José Roca

  • Administrator
  • Hero Member
  • *****
  • Posts: 2483
  • User-Rate: +204/-0
OpenGL: molehill
« on: July 25, 2008, 09:14:16 PM »
molehill uses the GLU NURBS routines to draw some nice surfaces.

Code: [Select]
'/* Copyright (c) Mark J. Kilgard, 1995. */

'/* This program is freely distributable without licensing fees
'   and is provided without guarantee or warrantee expressed or
'   implied. This program is -not- in the public domain. */

'/* molehill uses the GLU NURBS routines to draw some nice surfaces. */

' Translated and adapted to PowerBASIC by José Roca, 2007

' SED_PBWIN - Use the PBWIN compiler
#COMPILE EXE
#DIM ALL
#INCLUDE "GLU.INC"

$WindowCaption = "molehill"

%GL_WINDOWWIDTH  = 640         ' Window width
%GL_WINDOWHEIGHT = 480         ' Window height
%GL_BITSPERPEL   = 16          ' Color resolution in bits per pixel
%GL_DEPTHBITS    = 16          ' Depth of the depth (z-axis) buffer

GLOBAL hDC AS LONG             ' Device context handle

' =======================================================================================
' All the setup goes here
' =======================================================================================
SUB SetupScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   LOCAL nurb AS DWORD
   LOCAL u, v AS LONG

   DIM mat_red_diffuse(3) AS SINGLE
   ARRAY ASSIGN mat_red_diffuse() = 0.7, 0.0, 0.1, 1.0
   DIM mat_green_diffuse(3) AS SINGLE
   ARRAY ASSIGN mat_green_diffuse() = 0.0, 0.7, 0.1, 1.0
   DIM mat_blue_diffuse(3) AS SINGLE
   ARRAY ASSIGN mat_blue_diffuse() = 0.0, 0.1, 0.7, 1.0
   DIM mat_yellow_diffuse(3) AS SINGLE
   ARRAY ASSIGN mat_yellow_diffuse() = 0.7, 0.8, 0.1, 1.0
   DIM mat_specular(3) AS SINGLE
   ARRAY ASSIGN mat_specular() = 1.0, 1.0, 1.0, 1.0
   DIM mat_shininess(0) AS SINGLE
   ARRAY ASSIGN mat_shininess() = 100.0
   DIM knots(7) AS SINGLE
   ARRAY ASSIGN knots() = 0.0, 0.0, 0.0, 0.0, 1.0, 1.0, 1.0, 1.0

   DIM pts1(2, 3, 3) AS SINGLE
   DIM pts2(2, 3, 3) AS SINGLE
   DIM pts3(2, 3, 3) AS SINGLE
   DIM pts4(2, 3, 3) AS SINGLE

   glMaterialfv %GL_FRONT, %GL_SPECULAR, mat_specular(0)
   glMaterialfv %GL_FRONT, %GL_SHININESS, mat_shininess(0)
   glEnable %GL_LIGHTING
   glEnable %GL_LIGHT0
   glEnable %GL_DEPTH_TEST
   glEnable %GL_AUTO_NORMAL
   glEnable %GL_NORMALIZE
   nurb = gluNewNurbsRenderer
   gluNurbsProperty nurb, %GLU_SAMPLING_TOLERANCE, 25.0
   gluNurbsProperty nurb, %GLU_DISPLAY_MODE, %GLU_FILL

   ' /* Build control points for NURBS mole hills. */
   FOR u = 0 TO 3
      FOR v = 0 TO 3
         '/* Red. */
         pts1(0, v, u) = 2.0 * u
         pts1(1, v, u) = 2.0 * v
         IF  (u=1 OR u = 2) AND (v = 1 OR v = 2) THEN
            ' /* Stretch up middle. */
            pts1(2, v, u) = 6.0
         ELSE
            pts1(2, v, u) = 0.0
         END IF
         ' /* Green. */
         pts2(0, v, u) = 2.0 * (u - 3.0)
         pts2(1, v, u) = 2.0 * (v - 3.0)
         IF (u=1 OR u = 2) AND (v = 1 OR v = 2) THEN
            IF u = 1 AND v = 1 THEN
               ' /* Pull hard on single middle square. */
               pts2(2, v, u) = 15.0
            ELSE
               ' /* Push down on other middle squares. */
               pts2(2, v, u) = -2.0
            END IF
         ELSE
            pts2(2, v, u) = 0.0
         END IF
         ' /* Blue. */
         pts3(0, v, u) = 2.0 * (u - 3.0)
         pts3(1, v, u) = 2.0 * v
         IF (u=1 OR u = 2) AND (v = 1 OR v = 2) THEN
            IF u = 1 AND v = 2 THEN
               ' /* Pull up on single middple square. */
               pts3(2, v, u) = 11.0
            ELSE
               ' /* Pull up slightly on other middle squares. */
               pts3(2, v, u) = 2.0
            END IF
         ELSE
            pts3(2, v, u) = 0.0
         END IF
         ' /* Yellow. */
         pts4(0, v, u) = 2.0 * u
         pts4(1, v, u) = 2.0 * (v - 3.0)
         IF (u=1 OR u = 2 OR u = 3) AND (v = 1 OR v = 2) THEN
            IF v = 1 THEN
               ' /* Push down front middle and right squares. */
               pts4(2, v, u) = -2.0
            ELSE
               ' /* Pull up back middle and right squares. */
               pts4(2, v, u) = 5.0
            END IF
         ELSE
            pts4(2, v, u) = 0.0
         END IF
      NEXT
   NEXT

   ' /* Stretch up red's far right corner. */
   pts1(2, 3, 3) = 6
   ' /* Pull down green's near left corner a little. */
   pts2(2, 0, 0) = -2
   ' /* Turn up meeting of four corners. */
   pts1(2, 0, 0) = 1
   pts2(2, 3, 3) = 1
   pts3(2, 0, 3) = 1
   pts4(2, 3, 0) = 1

   glMatrixMode %GL_PROJECTION
   gluPerspective 55.0, 1.0, 2.0, 24.0
   glMatrixMode %GL_MODELVIEW
   glTranslatef 0.0, 0.0, -15.0
   glRotatef 330.0, 1.0, 0.0, 0.0

   glNewList 1, %GL_COMPILE
   ' /* Render red hill. */
   glMaterialfv %GL_FRONT, %GL_DIFFUSE, mat_red_diffuse(0)
   gluBeginSurface nurb
      gluNurbsSurface nurb, 8, knots(0), 8, knots(0), _
        4 * 3, 3, pts1(0, 0, 0), _
        4, 4, %GL_MAP2_VERTEX_3
   gluEndSurface nurb

   ' /* Render green hill. */
   glMaterialfv %GL_FRONT, %GL_DIFFUSE, mat_green_diffuse(0)
   gluBeginSurface nurb
      gluNurbsSurface nurb, 8, knots(0), 8, knots(0), _
        4 * 3, 3, pts2(0, 0, 0), _
        4, 4, %GL_MAP2_VERTEX_3
   gluEndSurface nurb

   ' /* Render blue hill. */
   glMaterialfv %GL_FRONT, %GL_DIFFUSE, mat_blue_diffuse(0)
   gluBeginSurface nurb
      gluNurbsSurface nurb, 8, knots(0), 8, knots(0), _
        4 * 3, 3, pts3(0, 0, 0), _
        4, 4, %GL_MAP2_VERTEX_3
   gluEndSurface nurb

   ' /* Render yellow hill. */
   glMaterialfv %GL_FRONT, %GL_DIFFUSE, mat_yellow_diffuse(0)
   gluBeginSurface nurb
      gluNurbsSurface nurb, 8, knots(0), 8, knots(0), _
        4 * 3, 3, pts4(0, 0, 0), _
        4, 4, %GL_MAP2_VERTEX_3
   gluEndSurface nurb
   glEndList

END SUB
' =======================================================================================

' =======================================================================================
' Resize the scene
' =======================================================================================
SUB ResizeScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   ' Prevent divide by zero making height equal one
   IF nHeight = 0 THEN nHeight = 1
   ' Reset the current viewport
   glViewport 0, 0, nWidth, nHeight

END SUB
' =======================================================================================

' =======================================================================================
' Draw the scene
' =======================================================================================
SUB DrawScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   ' Clear the screen and depth buffers
   glClear %GL_COLOR_BUFFER_BIT OR %GL_DEPTH_BUFFER_BIT
   ' Call the list
   glCallList 1
   glFlush

END SUB
' =======================================================================================

' =======================================================================================
' Processes keystrokes
' Parameters:
' * hwnd = Window hande
' * vKeyCode = Virtual key code
' * bKeyDown = %TRUE if key is pressed; %FALSE if it is released
' =======================================================================================
SUB ProcessKeystrokes (BYVAL hwnd AS DWORD, BYVAL vKeyCode AS LONG, BYVAL bKeyDown AS LONG)

   SELECT CASE AS LONG vKeyCode

      CASE %VK_ESCAPE
         ' Quit if Esc key pressed
         SendMessage hwnd, %WM_CLOSE, 0, 0

   END SELECT

END SUB
' =======================================================================================

' =======================================================================================
' Main
' =======================================================================================
FUNCTION WINMAIN (BYVAL hInstance AS DWORD, BYVAL hPrevInstance AS DWORD, BYVAL lpszCmdLine AS ASCIIZ PTR, BYVAL nCmdShow AS LONG) AS LONG

   LOCAL  hwnd        AS DWORD
   LOCAL  wcex        AS WNDCLASSEX
   LOCAL  szClassName AS ASCIIZ * 256
   LOCAL  szCaption   AS ASCIIZ * 256
   LOCAL  msg         AS tagMSG
   LOCAL  rc          AS RECT
   LOCAL  bDone       AS LONG
   LOCAL  nLeft       AS LONG
   LOCAL  nTop        AS LONG
   LOCAL  nWidth      AS LONG
   LOCAL  nHeight     AS LONG
   LOCAL  dwStyle     AS DWORD
   LOCAL  dwStyleEx   AS DWORD
   STATIC vKeyCode    AS LONG
   STATIC bKeyDown    AS LONG
   LOCAL  t           AS DOUBLE
   LOCAL  t0          AS DOUBLE
   LOCAL  fps         AS DOUBLE
   LOCAL  nFrames     AS LONG
   LOCAL  dm          AS DEVMODE
   LOCAL  bFullScreen AS LONG
   LOCAL  lResult     AS LONG

   ' Register the window class
   szClassName        = "PBOPENGL"
   wcex.cbSize        = SIZEOF(wcex)
   wcex.style         = %CS_HREDRAW OR %CS_VREDRAW OR %CS_OWNDC
   wcex.lpfnWndProc   = CODEPTR(WndProc)
   wcex.cbClsExtra    = 0
   wcex.cbWndExtra    = 0
   wcex.hInstance     = hInstance
   wcex.hCursor       = LoadCursor (%NULL, BYVAL %IDC_ARROW)
   wcex.hbrBackground = %NULL
   wcex.lpszMenuName  = %NULL
   wcex.lpszClassName = VARPTR(szClassName)
   wcex.hIcon         = LoadIcon (%NULL, BYVAL %IDI_APPLICATION) ' Sample, if resource icon: LoadIcon(hInst, "APPICON")
   wcex.hIconSm       = LoadIcon (%NULL, BYVAL %IDI_APPLICATION) ' Remember to set small icon too..
   RegisterClassEx wcex

   ' Ask the user which screen mode he prefers
   lResult = MessageBox(%NULL, "Would you like to run in fullscreen mode?", _
             "Start fullScreen?", %MB_YESNOCANCEL OR %MB_ICONQUESTION)
   SELECT CASE lResult
      CASE %IDCANCEL : EXIT FUNCTION
      CASE %IDYES    : bFullScreen = %TRUE
      CASE %IDNO     : bFullScreen = %FALSE
   END SELECT

   ' Window size
   nWidth  = %GL_WINDOWWIDTH
   nHeight = %GL_WINDOWHEIGHT

   IF bFullScreen THEN
      ' Change display settings
      dm.dmSize       = SIZEOF(dm)
      dm.dmPelsWidth  = nWidth
      dm.dmPelsHeight = nHeight
      dm.dmBitsPerPel = %GL_BITSPERPEL
      dm.dmFields     = %DM_BITSPERPEL OR %DM_PELSWIDTH OR %DM_PELSHEIGHT
      IF ChangeDisplaySettings(dm, %CDS_FULLSCREEN) = 0 THEN ShowCursor %FALSE
   END IF

   ' Window caption
   szCaption = $WindowCaption

   ' Window styles
   IF ISFALSE bFullScreen THEN
      dwStyle = %WS_OVERLAPPEDWINDOW
      dwStyleEx = %WS_EX_APPWINDOW OR %WS_EX_WINDOWEDGE
   ELSE
      dwStyle = %WS_POPUP
      dwStyleEx = %WS_EX_APPWINDOW
   END IF

   ' Create the window
   hwnd = CreateWindowEx( _
            dwStyleEx, _                      ' extended styles
            szClassName, _                    ' window class name
            szCaption, _                      ' window caption
            dwStyle, _                        ' window style
            nLeft, _                          ' initial x position
            nTop, _                           ' initial y position
            nWidth, _                         ' initial x size
            nHeight, _                        ' initial y size
            %NULL, _                          ' parent window handle
            0, _                              ' window menu handle
            hInstance, _                      ' program instance handle
            BYVAL %NULL)                      ' creation parameters

   ' Retrieve the coordinates of the window's client area
   GetClientRect hwnd, rc
   ' Initialize the new OpenGl window
   SetupScene hwnd, rc.nRight - rc.nLeft, rc.nBottom - rc.nTop

   ' Show the window
   ShowWindow hwnd, nCmdShow
   UpdateWindow hwnd

   DO UNTIL bDone

      ' Windows message pump
      DO WHILE PeekMessage(msg, %NULL, 0, 0, %PM_REMOVE)
         IF msg.message = %WM_QUIT THEN
            bDone = %TRUE
         ELSE
            IF msg.message = %WM_KEYDOWN THEN
               vKeyCode = msg.wParam
               bKeyDown = %TRUE
            ELSEIF msg.message = %WM_KEYUP THEN
               vKeyCode = msg.wParam
               bKeyDown = %FALSE
            END IF
            TranslateMessage msg
            DispatchMessage msg
         END IF
      LOOP

      IF ISFALSE bFullScreen THEN
         ' Get time and mouse position
         t = INT(TIMER)
         ' Calculate and display FPS (frames per second)
         IF t > t0 OR nFrames = 0 THEN
            fps = nFrames \ (t - t0)
            wsprintf szCaption, $WindowCaption & " (%i FPS)", BYVAL fps
            SetWindowText hwnd, szCaption
            t0 = t
            nFrames = 0
         END IF
         nFrames = nFrames + 1
      END IF

      ' Draw the scene
      DrawScene hwnd, nWidth, nHeight
      ' Exchange the front and back buffers
      SwapBuffers hDC

      ' Process the keystrokes
      IF vKeyCode THEN
         ProcessKeystrokes hwnd, vKeyCode, bKeyDown
         vKeyCode = 0
      END IF

   LOOP

   ' Retore defaults
   IF bFullScreen THEN
      ChangeDisplaySettings BYVAL %NULL, 0
      ShowCursor %TRUE
   END IF

   FUNCTION = msg.wParam

END FUNCTION
' =======================================================================================

' =======================================================================================
' Main window procedure
' =======================================================================================
FUNCTION WndProc (BYVAL hwnd AS DWORD, BYVAL wMsg AS DWORD, BYVAL wParam AS DWORD, BYVAL lParam AS LONG) AS LONG

   LOCAL  pf           AS LONG
   LOCAL  pfd          AS PIXELFORMATDESCRIPTOR
   STATIC hRC          AS LONG

   SELECT CASE wMsg

      CASE %WM_SYSCOMMAND

         ' Disable the Windows screensaver
         IF (wParam AND &HFFF0) = %SC_SCREENSAVE THEN EXIT FUNCTION

         ' Close the window
         IF (wParam AND &HFFF0) = %SC_CLOSE THEN
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

      CASE %WM_CREATE

         ' Retrieve the device context handle
         hDC = GetDC(hwnd)

         ' Fill the PIXELFORMATDESCRIPTOR structure
         pfd.nSize           = SIZEOF(PIXELFORMATDESCRIPTOR)   ' Size of the structure
         pfd.nVersion        = 1                               ' Version number
         pfd.dwFlags         = %PFD_DRAW_TO_WINDOW _           ' Format must support window
                               OR %PFD_SUPPORT_OPENGL _        ' Format must support OpenGL
                               OR %PFD_DOUBLEBUFFER            ' Format must support double buffering
         pfd.iPixelType      = %PFD_TYPE_RGBA                  ' Request an RGBA format
         pfd.cColorBits      = %GL_BITSPERPEL                  ' Number of color bitplanes in each color buffer
         pfd.cRedBits        = 0                               ' Number of red bitplanes in each RGBA color buffer.
         pfd.cRedShift       = 0                               ' Shift count for red bitplanes in each RGBA color buffer.
         pfd.cGreenBits      = 0                               ' Number of green bitplanes in each RGBA color buffer.
         pfd.cGreenShift     = 0                               ' Shift count for green bitplanes in each RGBA color buffer.
         pfd.cBlueBits       = 0                               ' Number of blue bitplanes in each RGBA color buffer.
         pfd.cBlueShift      = 0                               ' Shift count for blue bitplanes in each RGBA color buffer.
         pfd.cAlphaBits      = 0                               ' Number of alpha bitplanes in each RGBA color buffer
         pfd.cAlphaShift     = 0                               ' Shift count for alpha bitplanes in each RGBA color buffer.
         pfd.cAccumBits      = 0                               ' Total number of bitplanes in the accumulation buffer.
         pfd.cAccumRedBits   = 0                               ' Number of red bitplanes in the accumulation buffer.
         pfd.cAccumGreenBits = 0                               ' Number of gree bitplanes in the accumulation buffer.
         pfd.cAccumBlueBits  = 0                               ' Number of blue bitplanes in the accumulation buffer.
         pfd.cAccumAlphaBits = 0                               ' Number of alpha bitplanes in the accumulation buffer.
         pfd.cDepthBits      = %GL_DEPTHBITS                   ' Depth of the depth (z-axis) buffer.
         pfd.cStencilBits    = 0                               ' Depth of the stencil buffer.
         pfd.cAuxBuffers     = 0                               ' Number of auxiliary buffers.
         pfd.iLayerType      = %PFD_MAIN_PLANE                 ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.
         pfd.bReserved       = 0                               ' Number of overlay and underlay planes.
         pfd.dwLayerMask     = 0                               ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.
         pfd.dwVisibleMask   = 0                               ' Transparent color or index of an underlay plane.
         pfd.dwDamageMask    = 0                               ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.

         ' Find a matching pixel format
         pf = ChoosePixelFormat(hDC, pfd)
         IF ISFALSE pf THEN
            MessageBox hwnd, "Can't find a suitable pixel format", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Set the pixel format
         IF ISFALSE SetPixelFormat(hDC, pf, pfd) THEN
            MessageBox hwnd, "Can't set the pixel format", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Create a new OpenGL rendering context
         hRC = wglCreateContext(hDC)
         IF ISFALSE hRC THEN
            MessageBox hwnd, "Can't create an OpenGL rendering context", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Make it current
         IF ISFALSE wglMakeCurrent(hDC,hRC) THEN
            MessageBox hwnd, "Can't activate the OpenGL rendering context", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         EXIT FUNCTION

      CASE %WM_DESTROY
         ' Release the device and rendering contexts
         wglMakeCurrent hDC, 0
         ' Make the rendering context no longer current
         wglDeleteContext hRC
         ' Release the device context
         ReleaseDC hwnd, hDC
         ' Post an WM_QUIT message
         PostQuitMessage 0
         EXIT FUNCTION

      CASE %WM_SIZE
         ResizeScene hwnd, LO(WORD, lParam), HI(WORD, lParam)
         EXIT FUNCTION

   END SELECT

   ' Call the default window procedure to process unhandled messages
   FUNCTION = DefWindowProc(hwnd, wMsg, wParam, lParam)

END FUNCTION
' =======================================================================================


« Last Edit: August 07, 2011, 08:00:15 PM by José Roca »

Offline José Roca

  • Administrator
  • Hero Member
  • *****
  • Posts: 2483
  • User-Rate: +204/-0
Re: OpenGL: molehill [GLFW Version]
« Reply #1 on: September 16, 2008, 02:07:59 AM »
 
molehill uses the GLU NURBS routines to draw some nice surfaces.

Code: [Select]
'/* Copyright (c) Mark J. Kilgard, 1995. */

'/* This program is freely distributable without licensing fees
'   and is provided without guarantee or warrantee expressed or
'   implied. This program is -not- in the public domain. */

'/* molehill uses the GLU NURBS routines to draw some nice surfaces. */

' Translated and adapted to PowerBASIC by José Roca, 2007

' SED_PBWIN - Use the PBWIN compiler
#COMPILE EXE
#DIM ALL
#INCLUDE "GLFW.INC"

FUNCTION PBMAIN () AS LONG

   LOCAL nWidth, nHeight, running, frames, x, y AS LONG
   LOCAL t, t0, fps AS DOUBLE
   LOCAL szTitlestr AS ASCIIZ * 200
   LOCAL nurb AS DWORD
   LOCAL u, v AS LONG

   ' Initialize GLFW
   glfwInit

   ' Open OpenGL window
   IF ISFALSE glfwOpenWindow(640, 480, 0, 0, 0, 0, 16, 0, %GLFW_WINDOW) THEN
      glfwTerminate
      EXIT FUNCTION
   END IF

   DIM mat_red_diffuse(3) AS SINGLE
   ARRAY ASSIGN mat_red_diffuse() = 0.7, 0.0, 0.1, 1.0
   DIM mat_green_diffuse(3) AS SINGLE
   ARRAY ASSIGN mat_green_diffuse() = 0.0, 0.7, 0.1, 1.0
   DIM mat_blue_diffuse(3) AS SINGLE
   ARRAY ASSIGN mat_blue_diffuse() = 0.0, 0.1, 0.7, 1.0
   DIM mat_yellow_diffuse(3) AS SINGLE
   ARRAY ASSIGN mat_yellow_diffuse() = 0.7, 0.8, 0.1, 1.0
   DIM mat_specular(3) AS SINGLE
   ARRAY ASSIGN mat_specular() = 1.0, 1.0, 1.0, 1.0
   DIM mat_shininess(0) AS SINGLE
   ARRAY ASSIGN mat_shininess() = 100.0
   DIM knots(7) AS SINGLE
   ARRAY ASSIGN knots() = 0.0, 0.0, 0.0, 0.0, 1.0, 1.0, 1.0, 1.0

   DIM pts1(2, 3, 3) AS SINGLE
   DIM pts2(2, 3, 3) AS SINGLE
   DIM pts3(2, 3, 3) AS SINGLE
   DIM pts4(2, 3, 3) AS SINGLE

   glMaterialfv %GL_FRONT, %GL_SPECULAR, mat_specular(0)
   glMaterialfv %GL_FRONT, %GL_SHININESS, mat_shininess(0)
   glEnable %GL_LIGHTING
   glEnable %GL_LIGHT0
   glEnable %GL_DEPTH_TEST
   glEnable %GL_AUTO_NORMAL
   glEnable %GL_NORMALIZE
   nurb = gluNewNurbsRenderer
   gluNurbsProperty nurb, %GLU_SAMPLING_TOLERANCE, 25.0
   gluNurbsProperty nurb, %GLU_DISPLAY_MODE, %GLU_FILL

   ' /* Build control points for NURBS mole hills. */
   FOR u = 0 TO 3
      FOR v = 0 TO 3
         '/* Red. */
         pts1(0, v, u) = 2.0 * u
         pts1(1, v, u) = 2.0 * v
         IF  (u=1 OR u = 2) AND (v = 1 OR v = 2) THEN
            ' /* Stretch up middle. */
            pts1(2, v, u) = 6.0
         ELSE
            pts1(2, v, u) = 0.0
         END IF
         ' /* Green. */
         pts2(0, v, u) = 2.0 * (u - 3.0)
         pts2(1, v, u) = 2.0 * (v - 3.0)
         IF (u=1 OR u = 2) AND (v = 1 OR v = 2) THEN
            IF u = 1 AND v = 1 THEN
               ' /* Pull hard on single middle square. */
               pts2(2, v, u) = 15.0
            ELSE
               ' /* Push down on other middle squares. */
               pts2(2, v, u) = -2.0
            END IF
         ELSE
            pts2(2, v, u) = 0.0
         END IF
         ' /* Blue. */
         pts3(0, v, u) = 2.0 * (u - 3.0)
         pts3(1, v, u) = 2.0 * v
         IF (u=1 OR u = 2) AND (v = 1 OR v = 2) THEN
            IF u = 1 AND v = 2 THEN
               ' /* Pull up on single middple square. */
               pts3(2, v, u) = 11.0
            ELSE
               ' /* Pull up slightly on other middle squares. */
               pts3(2, v, u) = 2.0
            END IF
         ELSE
            pts3(2, v, u) = 0.0
         END IF
         ' /* Yellow. */
         pts4(0, v, u) = 2.0 * u
         pts4(1, v, u) = 2.0 * (v - 3.0)
         IF (u=1 OR u = 2 OR u = 3) AND (v = 1 OR v = 2) THEN
            IF v = 1 THEN
               ' /* Push down front middle and right squares. */
               pts4(2, v, u) = -2.0
            ELSE
               ' /* Pull up back middle and right squares. */
               pts4(2, v, u) = 5.0
            END IF
         ELSE
            pts4(2, v, u) = 0.0
         END IF
      NEXT
   NEXT

   ' /* Stretch up red's far right corner. */
   pts1(2, 3, 3) = 6
   ' /* Pull down green's near left corner a little. */
   pts2(2, 0, 0) = -2
   ' /* Turn up meeting of four corners. */
   pts1(2, 0, 0) = 1
   pts2(2, 3, 3) = 1
   pts3(2, 0, 3) = 1
   pts4(2, 3, 0) = 1

   glMatrixMode %GL_PROJECTION
   gluPerspective 55.0, 1.0, 2.0, 24.0
   glMatrixMode %GL_MODELVIEW
   glTranslatef 0.0, 0.0, -15.0
   glRotatef 330.0, 1.0, 0.0, 0.0

   glNewList 1, %GL_COMPILE
   ' /* Render red hill. */
   glMaterialfv %GL_FRONT, %GL_DIFFUSE, mat_red_diffuse(0)
   gluBeginSurface nurb
      gluNurbsSurface nurb, 8, knots(0), 8, knots(0), _
        4 * 3, 3, pts1(0, 0, 0), _
        4, 4, %GL_MAP2_VERTEX_3
   gluEndSurface nurb

   ' /* Render green hill. */
   glMaterialfv %GL_FRONT, %GL_DIFFUSE, mat_green_diffuse(0)
   gluBeginSurface nurb
      gluNurbsSurface nurb, 8, knots(0), 8, knots(0), _
        4 * 3, 3, pts2(0, 0, 0), _
        4, 4, %GL_MAP2_VERTEX_3
   gluEndSurface nurb

   ' /* Render blue hill. */
   glMaterialfv %GL_FRONT, %GL_DIFFUSE, mat_blue_diffuse(0)
   gluBeginSurface nurb
      gluNurbsSurface nurb, 8, knots(0), 8, knots(0), _
        4 * 3, 3, pts3(0, 0, 0), _
        4, 4, %GL_MAP2_VERTEX_3
   gluEndSurface nurb

   ' /* Render yellow hill. */
   glMaterialfv %GL_FRONT, %GL_DIFFUSE, mat_yellow_diffuse(0)
   gluBeginSurface nurb
      gluNurbsSurface nurb, 8, knots(0), 8, knots(0), _
        4 * 3, 3, pts4(0, 0, 0), _
        4, 4, %GL_MAP2_VERTEX_3
   gluEndSurface nurb
   glEndList

   ' Enable sticky keys
   glfwEnable %GLFW_STICKY_KEYS

   ' Main loop
   running = %TRUE
   frames = 0
   t0 = glfwGetTime

   DO WHILE running

      ' Get time and mouse position
      t = glfwGetTime
      glfwGetMousePos x, y
      ' Calculate and display FPS (frames per second)
      IF t - t0 > 1.0! OR frames = 0 THEN
         fps = frames / (t-t0)
         wsprintf szTitlestr, "molehill (%i FPS)", BYVAL fps
         glfwSetWindowTitle szTitlestr
         t0 = t
         frames = 0
      END IF
      frames = frames + 1

      '  Get window size (may be different than the requested size)
      glfwGetWindowSize nWidth, nHeight
      IF nHeight <= 0 THEN nHeight = 1

      ' Set viewport
      glViewport 0, 0, nWidth, nHeight

      ' Clear the screen and depth buffers
      glClear %GL_COLOR_BUFFER_BIT OR %GL_DEPTH_BUFFER_BIT
      ' Call the list
      glCallList 1
      glFlush

      ' Swap buffers
      glfwSwapBuffers

      ' Check if the ESC key was pressed or the window was closed
      running = NOT glfwGetKey(%GLFW_KEY_ESC) AND glfwGetWindowParam(%GLFW_OPENED)

   LOOP

   ' Close OpenGL window and terminate GLFW
   glfwTerminate

END FUNCTION
« Last Edit: August 07, 2011, 08:00:33 PM by José Roca »