Author Topic: NeHe Lesson 09: Moving Bitmaps In 3D Space  (Read 3491 times)

0 Members and 1 Guest are viewing this topic.

Offline José Roca

  • Administrator
  • Hero Member
  • *****
  • Posts: 2481
NeHe Lesson 09: Moving Bitmaps In 3D Space
« on: July 25, 2008, 08:24:56 PM »
 
This example illustrates how to move objects around the screen.

It is an adaptation of NeeHe Lesson 09: http://nehe.gamedev.net/data/lessons/lesson.asp?lesson=09

Code: [Select]
' SED_PBWIN - Use the PBWIN compiler
#COMPILE EXE
#DIM ALL
#INCLUDE "GLU.INC"
#INCLUDE "GDIPLUS.INC"
#INCLUDE "GDIPUTILS.INC"

$WindowCaption = "NeHe Lesson 09"

%GL_WINDOWWIDTH  = 640         ' Window width
%GL_WINDOWHEIGHT = 480         ' Window height
%GL_BITSPERPEL   = 16          ' Color resolution in bits per pixel
%GL_DEPTHBITS    = 16          ' Depth of the depth (z-axis) buffer

GLOBAL hDC AS LONG             ' Device context handle

%NUMSTARS = 50

TYPE Stars
   r     AS LONG
   g     AS LONG
   b     AS LONG
   Dist  AS SINGLE
   Angle AS SINGLE
END TYPE

GLOBAL TextureHandle AS DWORD
GLOBAL Star() AS Stars
GLOBAL zoom AS SINGLE
GLOBAL Tilt AS SINGLE
GLOBAL Spin AS SINGLE
GLOBAL Twinkle AS LONG

' =======================================================================================
' All the setup goes here
' =======================================================================================
SUB SetupScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   LOCAL hr AS LONG
   LOCAL strTextureData AS STRING
   LOCAL TextureWidth, TextureHeight AS LONG
   LOCAL i AS LONG

   REDIM Star(%NUMSTARS) AS Stars

   ' Load bitmap texture from disk
   hr = GdiPlusLoadTexture("star.bmp", TextureWidth, TextureHeight, strTextureData, %TRUE)

   Zoom = -15!
   Tilt = 90.0!

   ' Assign an OpenGL handle to this texture
   glGenTextures 1, TextureHandle

   ' Create Linear Filtered Texture
   glBindTexture %GL_TEXTURE_2D, TextureHandle
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_LINEAR
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_LINEAR
   glTexImage2D %GL_TEXTURE_2D, 0, 3, TextureWidth, TextureHeight, 0, _
                %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Enable texture mapping
   glEnable(%GL_TEXTURE_2D)
   ' Select smooth shading
   glShadeModel %GL_SMOOTH
   ' Specify clear values for the color buffers
   glClearColor 0.0!, 0.0!, 0.0!, 0.0!
   ' Specify the clear value for the depth buffer
   glClearDepth 1.0!

   ' Drop OpenGL hints how to render our graphics
   glHint %GL_POINT_SMOOTH_HINT, %GL_NICEST
   glHint %GL_LINE_SMOOTH_HINT, %GL_NICEST
   glHint %GL_POLYGON_SMOOTH_HINT, %GL_NICEST
   glHint %GL_FOG_HINT, %GL_NICEST
   glHint %GL_PERSPECTIVE_CORRECTION_HINT, %GL_NICEST

   ' Set the blending function for translucency
   glBlendFunc %GL_SRC_ALPHA,%GL_ONE
   glEnable %GL_BLEND

   FOR i = 0 TO %NUMSTARS -1
      Star(i).Angle = 0.0!
      Star(i).Dist = (i / %NUMSTARS) * 5.0! ' Calculate distance from the center
      Star(i).r = RND(0, 255)               ' Give star[loop] a random red intensity
      Star(i).g = RND(0, 255)               ' Give star[loop] a random green intensity
      Star(i).b = RND(0, 255)               ' Give star[loop] a random blue intensity
   NEXT i

END SUB
' =======================================================================================

' =======================================================================================
' Resize the scene
' =======================================================================================
SUB ResizeScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   ' Prevent divide by zero making height equal one
   IF nHeight = 0 THEN nHeight = 1
   ' Reset the current viewport
   glViewport 0, 0, nWidth, nHeight
   ' Select the projection matrix
   glMatrixMode %GL_PROJECTION
   ' Reset the projection matrix
   glLoadIdentity
   ' Calculate the aspect ratio of the window
   gluPerspective 45.0!, nWidth / nHeight, 0.1!, 100.0!
   ' Select the model view matrix
   glMatrixMode %GL_MODELVIEW
   ' Reset the model view matrix
   glLoadIdentity

END SUB
' =======================================================================================

' =======================================================================================
' Draw the scene
' =======================================================================================
SUB DrawScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   LOCAL i AS LONG

   ' Clear the screen buffer
   glClear %GL_COLOR_BUFFER_BIT OR %GL_DEPTH_BUFFER_BIT
   ' Reset the view
   glLoadIdentity

   FOR i = 0 TO %NUMSTARS - 1
      glLoadIdentity
      glTranslatef 0.0!, 0.0!, Zoom
      glRotatef Tilt, 1.0!, 0.0!, 0.0!

      glRotatef Star(i).Angle, 0.0!, 1.0!, 0.0!
      glTranslatef Star(i).Dist, 0.0!, 0.0!

      glRotatef -Star(i).Angle, 0.0!, 1.0!, 0.0!
      glRotatef -Tilt, 1.0!, 0.0!, 0.0!

      IF Twinkle THEN
         ' Assign a color using bytes
         glColor4ub Star((%NUMSTARS - i) - 1).r, Star((%NUMSTARS - i) - 1).g, Star((%NUMSTARS - i) - 1).b, 255
         glBegin %GL_QUADS
            glTexCoord2f  0.0!,  0.0!: glVertex3f -1.0!, -1.0!,  0.0!
            glTexCoord2f  1.0!,  0.0!: glVertex3f  1.0!, -1.0!,  0.0!
            glTexCoord2f  1.0!,  1.0!: glVertex3f  1.0!,  1.0!,  0.0!
            glTexCoord2f  0.0!,  1.0!: glVertex3f -1.0!,  1.0!,  0.0!
         glEnd
      END IF

      glRotatef Spin, 0.0!, 0.0!, 1.0!

      ' Assign a color using bytes
      glColor4ub Star(i).r, Star(i).g, Star(i).b, 255
      glBegin %GL_QUADS
         glTexCoord2f  0.0!,  0.0!: glVertex3f -1.0!, -1.0!,  0.0!
         glTexCoord2f  1.0!,  0.0!: glVertex3f  1.0!, -1.0!,  0.0!
         glTexCoord2f  1.0!,  1.0!: glVertex3f  1.0!,  1.0!,  0.0!
         glTexCoord2f  0.0!,  1.0!: glVertex3f -1.0!,  1.0!,  0.0!
      glEnd

      Spin = Spin + 0.01!
      Star(i).Angle = Star(i).Angle + (i / %NUMSTARS)
      Star(i).Dist = Star(i).Dist - 0.01!

      IF Star(i).Dist < 0.0! THEN
         star(i).Dist = Star(i).Dist + 5!
         star(i).r = RND(0, 255)
         star(i).g = RND(0, 255)
         star(i).b = RND(0, 255)
      END IF
   NEXT

END SUB
' =======================================================================================

' =======================================================================================
' Cleanup
' =======================================================================================
SUB Cleanup (BYVAL hwnd AS DWORD)

   ' Delete the texture
   IF TextureHandle THEN glDeleteTextures(1, TextureHandle)

END SUB
' =======================================================================================

' =======================================================================================
' Processes keystrokes
' Parameters:
' * hwnd = Window hande
' * vKeyCode = Virtual key code
' * bKeyDown = %TRUE if key is pressed; %FALSE if it is released
' =======================================================================================
SUB ProcessKeystrokes (BYVAL hwnd AS DWORD, BYVAL vKeyCode AS LONG, BYVAL bKeyDown AS LONG)

   STATIC tp AS LONG

   SELECT CASE AS LONG vKeyCode

      CASE %VK_ESCAPE
         ' Quit if Esc key pressed
         SendMessage hwnd, %WM_CLOSE, 0, 0

      CASE %VK_T
         IF ISTRUE bKeyDown AND ISFALSE tp THEN
            tp = %TRUE
            Twinkle = NOT Twinkle
         END IF
         IF ISFALSE bKeyDown THEN tp = %FALSE

      CASE %VK_PGUP
         IF ISTRUE bKeyDown THEN Zoom = Zoom - 0.02!

      CASE %VK_PGDN
         IF ISTRUE bKeyDown THEN Zoom = Zoom + 0.02!

      CASE %VK_LEFT
         IF ISTRUE bKeyDown THEN Tilt = Tilt - 0.5!

      CASE %VK_RIGHT
         IF ISTRUE bKeyDown THEN Tilt = Tilt + 0.5!

   END SELECT

END SUB
' =======================================================================================

' =======================================================================================
' Main
' =======================================================================================
FUNCTION WINMAIN (BYVAL hInstance AS DWORD, BYVAL hPrevInstance AS DWORD, BYVAL lpszCmdLine AS ASCIIZ PTR, BYVAL nCmdShow AS LONG) AS LONG

   LOCAL  hwnd        AS DWORD
   LOCAL  wcex        AS WNDCLASSEX
   LOCAL  szClassName AS ASCIIZ * 256
   LOCAL  szCaption   AS ASCIIZ * 256
   LOCAL  msg         AS tagMSG
   LOCAL  rc          AS RECT
   LOCAL  bDone       AS LONG
   LOCAL  nLeft       AS LONG
   LOCAL  nTop        AS LONG
   LOCAL  nWidth      AS LONG
   LOCAL  nHeight     AS LONG
   LOCAL  dwStyle     AS DWORD
   LOCAL  dwStyleEx   AS DWORD
   STATIC vKeyCode    AS LONG
   STATIC bKeyDown    AS LONG
   LOCAL  t           AS DOUBLE
   LOCAL  t0          AS DOUBLE
   LOCAL  fps         AS DOUBLE
   LOCAL  nFrames     AS LONG
   LOCAL  dm          AS DEVMODE
   LOCAL  bFullScreen AS LONG
   LOCAL  lResult     AS LONG

   ' Register the window class
   szClassName        = "PBOPENGL"
   wcex.cbSize        = SIZEOF(wcex)
   wcex.style         = %CS_HREDRAW OR %CS_VREDRAW OR %CS_OWNDC
   wcex.lpfnWndProc   = CODEPTR(WndProc)
   wcex.cbClsExtra    = 0
   wcex.cbWndExtra    = 0
   wcex.hInstance     = hInstance
   wcex.hCursor       = LoadCursor (%NULL, BYVAL %IDC_ARROW)
   wcex.hbrBackground = %NULL
   wcex.lpszMenuName  = %NULL
   wcex.lpszClassName = VARPTR(szClassName)
   wcex.hIcon         = LoadIcon (%NULL, BYVAL %IDI_APPLICATION) ' Sample, if resource icon: LoadIcon(hInst, "APPICON")
   wcex.hIconSm       = LoadIcon (%NULL, BYVAL %IDI_APPLICATION) ' Remember to set small icon too..
   RegisterClassEx wcex

' Ask the user which screen mode he prefers
lResult = MessageBox(%NULL, "Would you like to run in fullscreen mode?", _
             "Start fullScreen?", %MB_YESNOCANCEL OR %MB_ICONQUESTION)
   SELECT CASE lResult
      CASE %IDCANCEL : EXIT FUNCTION
      CASE %IDYES    : bFullScreen = %TRUE
      CASE %IDNO     : bFullScreen = %FALSE
   END SELECT

   ' Window size
   nWidth  = %GL_WINDOWWIDTH
   nHeight = %GL_WINDOWHEIGHT

   IF bFullScreen THEN
      ' Change display settings
      dm.dmSize       = SIZEOF(dm)
      dm.dmPelsWidth  = nWidth
      dm.dmPelsHeight = nHeight
      dm.dmBitsPerPel = %GL_BITSPERPEL
      dm.dmFields     = %DM_BITSPERPEL OR %DM_PELSWIDTH OR %DM_PELSHEIGHT
      IF ChangeDisplaySettings(dm, %CDS_FULLSCREEN) = 0 THEN ShowCursor %FALSE
   END IF

   ' Window caption
   szCaption = $WindowCaption

   ' Window styles
   IF ISFALSE bFullScreen THEN
      dwStyle = %WS_OVERLAPPEDWINDOW
      dwStyleEx = %WS_EX_APPWINDOW OR %WS_EX_WINDOWEDGE
   ELSE
      dwStyle = %WS_POPUP
      dwStyleEx = %WS_EX_APPWINDOW
   END IF

   ' Create the window
   hwnd = CreateWindowEx( _
            dwStyleEx, _                      ' extended styles
            szClassName, _                    ' window class name
            szCaption, _                      ' window caption
            dwStyle, _                        ' window style
            nLeft, _                          ' initial x position
            nTop, _                           ' initial y position
            nWidth, _                         ' initial x size
            nHeight, _                        ' initial y size
            %NULL, _                          ' parent window handle
            0, _                              ' window menu handle
            hInstance, _                      ' program instance handle
            BYVAL %NULL)                      ' creation parameters

   ' Retrieve the coordinates of the window's client area
   GetClientRect hwnd, rc
   ' Initialize the new OpenGl window
   SetupScene hwnd, rc.nRight - rc.nLeft, rc.nBottom - rc.nTop

   ' Show the window
   ShowWindow hwnd, nCmdShow
   UpdateWindow hwnd

   DO UNTIL bDone

      ' Windows message pump
      DO WHILE PeekMessage(msg, %NULL, 0, 0, %PM_REMOVE)
         IF msg.message = %WM_QUIT THEN
            bDone = %TRUE
         ELSE
            IF msg.message = %WM_KEYDOWN THEN
               vKeyCode = msg.wParam
               bKeyDown = %TRUE
            ELSEIF msg.message = %WM_KEYUP THEN
               vKeyCode = msg.wParam
               bKeyDown = %FALSE
            END IF
            TranslateMessage msg
            DispatchMessage msg
         END IF
      LOOP

      IF ISFALSE bFullScreen THEN
         ' Get time and mouse position
         t = INT(TIMER)
         ' Calculate and display FPS (frames per second)
         IF t > t0 OR nFrames = 0 THEN
            fps = nFrames \ (t - t0)
            wsprintf szCaption, $WindowCaption & " (%i FPS)", BYVAL fps
            SetWindowText hwnd, szCaption
            t0 = t
            nFrames = 0
         END IF
         nFrames = nFrames + 1
      END IF

      ' Draw the scene
      DrawScene hwnd, nWidth, nHeight
      ' Exchange the front and back buffers
      SwapBuffers hDC

      ' Process the keystrokes
      IF vKeyCode THEN
         ProcessKeystrokes hwnd, vKeyCode, bKeyDown
         vKeyCode = 0
      END IF

   LOOP

   ' Retore defaults
   IF bFullScreen THEN
      ChangeDisplaySettings BYVAL %NULL, 0
      ShowCursor %TRUE
   END IF

   FUNCTION = msg.wParam

END FUNCTION
' =======================================================================================

' =======================================================================================
' Main window procedure
' =======================================================================================
FUNCTION WndProc (BYVAL hwnd AS DWORD, BYVAL wMsg AS DWORD, BYVAL wParam AS DWORD, BYVAL lParam AS LONG) AS LONG

   LOCAL  pf           AS LONG
   LOCAL  pfd          AS PIXELFORMATDESCRIPTOR
   STATIC hRC          AS LONG

   SELECT CASE wMsg

      CASE %WM_SYSCOMMAND

         ' Disable the Windows screensaver
         IF (wParam AND &HFFF0) = %SC_SCREENSAVE THEN EXIT FUNCTION

         ' Close the window
         IF (wParam AND &HFFF0) = %SC_CLOSE THEN
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

      CASE %WM_CREATE

         ' Retrieve the device context handle
         hDC = GetDC(hwnd)

         ' Fill the PIXELFORMATDESCRIPTOR structure
         pfd.nSize           = SIZEOF(PIXELFORMATDESCRIPTOR)   ' Size of the structure
         pfd.nVersion        = 1                               ' Version number
         pfd.dwFlags         = %PFD_DRAW_TO_WINDOW _           ' Format must support window
                               OR %PFD_SUPPORT_OPENGL _        ' Format must support OpenGL
                               OR %PFD_DOUBLEBUFFER            ' Format must support double buffering
         pfd.iPixelType      = %PFD_TYPE_RGBA                  ' Request an RGBA format
         pfd.cColorBits      = %GL_BITSPERPEL                  ' Number of color bitplanes in each color buffer
         pfd.cRedBits        = 0                               ' Number of red bitplanes in each RGBA color buffer.
         pfd.cRedShift       = 0                               ' Shift count for red bitplanes in each RGBA color buffer.
         pfd.cGreenBits      = 0                               ' Number of green bitplanes in each RGBA color buffer.
         pfd.cGreenShift     = 0                               ' Shift count for green bitplanes in each RGBA color buffer.
         pfd.cBlueBits       = 0                               ' Number of blue bitplanes in each RGBA color buffer.
         pfd.cBlueShift      = 0                               ' Shift count for blue bitplanes in each RGBA color buffer.
         pfd.cAlphaBits      = 0                               ' Number of alpha bitplanes in each RGBA color buffer
         pfd.cAlphaShift     = 0                               ' Shift count for alpha bitplanes in each RGBA color buffer.
         pfd.cAccumBits      = 0                               ' Total number of bitplanes in the accumulation buffer.
         pfd.cAccumRedBits   = 0                               ' Number of red bitplanes in the accumulation buffer.
         pfd.cAccumGreenBits = 0                               ' Number of gree bitplanes in the accumulation buffer.
         pfd.cAccumBlueBits  = 0                               ' Number of blue bitplanes in the accumulation buffer.
         pfd.cAccumAlphaBits = 0                               ' Number of alpha bitplanes in the accumulation buffer.
         pfd.cDepthBits      = %GL_DEPTHBITS                   ' Depth of the depth (z-axis) buffer.
         pfd.cStencilBits    = 0                               ' Depth of the stencil buffer.
         pfd.cAuxBuffers     = 0                               ' Number of auxiliary buffers.
         pfd.iLayerType      = %PFD_MAIN_PLANE                 ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.
         pfd.bReserved       = 0                               ' Number of overlay and underlay planes.
         pfd.dwLayerMask     = 0                               ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.
         pfd.dwVisibleMask   = 0                               ' Transparent color or index of an underlay plane.
         pfd.dwDamageMask    = 0                               ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.

         ' Find a matching pixel format
         pf = ChoosePixelFormat(hDC, pfd)
         IF ISFALSE pf THEN
            MessageBox hwnd, "Can't find a suitable pixel format", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Set the pixel format
         IF ISFALSE SetPixelFormat(hDC, pf, pfd) THEN
            MessageBox hwnd, "Can't set the pixel format", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Create a new OpenGL rendering context
         hRC = wglCreateContext(hDC)
         IF ISFALSE hRC THEN
            MessageBox hwnd, "Can't create an OpenGL rendering context", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Make it current
         IF ISFALSE wglMakeCurrent(hDC,hRC) THEN
            MessageBox hwnd, "Can't activate the OpenGL rendering context", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         EXIT FUNCTION

      CASE %WM_DESTROY
         ' Clear resources
         Cleanup hwnd
         ' Release the device and rendering contexts
         wglMakeCurrent hDC, 0
         ' Make the rendering context no longer current
         wglDeleteContext hRC
         ' Release the device context
         ReleaseDC hwnd, hDC
         ' Post an WM_QUIT message
         PostQuitMessage 0
         EXIT FUNCTION

      CASE %WM_SIZE
         ResizeScene hwnd, LO(WORD, lParam), HI(WORD, lParam)
         EXIT FUNCTION

   END SELECT

   ' Call the default window procedure to process unhandled messages
   FUNCTION = DefWindowProc(hwnd, wMsg, wParam, lParam)

END FUNCTION
' =======================================================================================


« Last Edit: August 07, 2011, 08:14:55 PM by José Roca »

Offline José Roca

  • Administrator
  • Hero Member
  • *****
  • Posts: 2481
Re: NeHe Lesson 09: Moving Bitmaps In 3D Space [SDL Version]
« Reply #1 on: July 27, 2008, 09:06:08 PM »
This example illustrates how to move objects around the screen.

It is an adaptation of NeeHe Lesson 09: http://nehe.gamedev.net/data/lessons/lesson.asp?lesson=09

Code: [Select]
' SED_PBWIN - Use the PBWIN compiler
#COMPILE EXE
#DIM ALL
#INCLUDE "SDL.INC"
#INCLUDE "GLU.INC"
#INCLUDE "GDIPUTILS.INC"

$WindowCaption = "NeHe Lesson 9"

%NUMSTARS = 50

TYPE Stars
   r     AS LONG
   g     AS LONG
   b     AS LONG
   Dist  AS SINGLE
   Angle AS SINGLE
END TYPE

GLOBAL TextureHandle AS DWORD
GLOBAL Star() AS Stars
GLOBAL zoom AS SINGLE
GLOBAL Tilt AS SINGLE
GLOBAL Spin AS SINGLE
GLOBAL Twinkle AS LONG

' =======================================================================================
' All the setup goes here
' =======================================================================================
SUB SetupScene ()

   LOCAL hr AS LONG
   LOCAL strTextureData AS STRING
   LOCAL TextureWidth, TextureHeight AS LONG
   LOCAL i AS LONG

   REDIM Star(%NUMSTARS) AS Stars

   ' Load bitmap texture from disk
   hr = GdiPlusLoadTexture("star.bmp", TextureWidth, TextureHeight, strTextureData, %TRUE)

   Zoom = -15!
   Tilt = 90.0!

   ' Assign an OpenGL handle to this texture
   glGenTextures 1, TextureHandle

   ' Create Linear Filtered Texture
   glBindTexture %GL_TEXTURE_2D, TextureHandle
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_LINEAR
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_LINEAR
   glTexImage2D %GL_TEXTURE_2D, 0, 3, TextureWidth, TextureHeight, 0, _
                %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Enable texture mapping
   glEnable(%GL_TEXTURE_2D)
   ' Select smooth shading
   glShadeModel %GL_SMOOTH
   ' Specify clear values for the color buffers
   glClearColor 0.0!, 0.0!, 0.0!, 0.0!
   ' Specify the clear value for the depth buffer
   glClearDepth 1.0!

   ' Drop OpenGL hints how to render our graphics
   glHint %GL_POINT_SMOOTH_HINT, %GL_NICEST
   glHint %GL_LINE_SMOOTH_HINT, %GL_NICEST
   glHint %GL_POLYGON_SMOOTH_HINT, %GL_NICEST
   glHint %GL_FOG_HINT, %GL_NICEST
   glHint %GL_PERSPECTIVE_CORRECTION_HINT, %GL_NICEST

   ' Set the blending function for translucency
   glBlendFunc %GL_SRC_ALPHA,%GL_ONE
   glEnable %GL_BLEND

   FOR i = 0 TO %NUMSTARS -1
      Star(i).Angle = 0.0!
      Star(i).Dist = (i / %NUMSTARS) * 5.0! ' Calculate distance from the center
      Star(i).r = RND(0, 255)               ' Give star[loop] a random red intensity
      Star(i).g = RND(0, 255)               ' Give star[loop] a random green intensity
      Star(i).b = RND(0, 255)               ' Give star[loop] a random blue intensity
   NEXT i

END SUB
' =======================================================================================

' =======================================================================================
' Draw the scene
' =======================================================================================
SUB DrawScene (BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   LOCAL i AS LONG

   ' Clear the screen buffer
   glClear %GL_COLOR_BUFFER_BIT OR %GL_DEPTH_BUFFER_BIT

   ' Select and setup the projection matrix
   glMatrixMode %GL_PROJECTION
   glLoadIdentity

   ' Prevent divide by zero making height equal one
   IF nHeight = 0 THEN nHeight = 1

   ' Calculate the aspect ratio of the window
   gluPerspective 45.0!, nWidth/nHeight, 1.0!, 100.0!

   ' Select and setup the modelview matrix
   glMatrixMode %GL_MODELVIEW
   glLoadIdentity

   FOR i = 0 TO %NUMSTARS - 1
      glLoadIdentity
      glTranslatef 0.0!, 0.0!, Zoom
      glRotatef Tilt, 1.0!, 0.0!, 0.0!

      glRotatef Star(i).Angle, 0.0!, 1.0!, 0.0!
      glTranslatef Star(i).Dist, 0.0!, 0.0!

      glRotatef -Star(i).Angle, 0.0!, 1.0!, 0.0!
      glRotatef -Tilt, 1.0!, 0.0!, 0.0!

      IF Twinkle THEN
         ' Assign a color using bytes
         glColor4ub Star((%NUMSTARS - i) - 1).r, Star((%NUMSTARS - i) - 1).g, Star((%NUMSTARS - i) - 1).b, 255
         glBegin %GL_QUADS
            glTexCoord2f  0.0!,  0.0!: glVertex3f -1.0!, -1.0!,  0.0!
            glTexCoord2f  1.0!,  0.0!: glVertex3f  1.0!, -1.0!,  0.0!
            glTexCoord2f  1.0!,  1.0!: glVertex3f  1.0!,  1.0!,  0.0!
            glTexCoord2f  0.0!,  1.0!: glVertex3f -1.0!,  1.0!,  0.0!
         glEnd
      END IF

      glRotatef Spin, 0.0!, 0.0!, 1.0!

      ' Assign a color using bytes
      glColor4ub Star(i).r, Star(i).g, Star(i).b, 255
      glBegin %GL_QUADS
         glTexCoord2f  0.0!,  0.0!: glVertex3f -1.0!, -1.0!,  0.0!
         glTexCoord2f  1.0!,  0.0!: glVertex3f  1.0!, -1.0!,  0.0!
         glTexCoord2f  1.0!,  1.0!: glVertex3f  1.0!,  1.0!,  0.0!
         glTexCoord2f  0.0!,  1.0!: glVertex3f -1.0!,  1.0!,  0.0!
      glEnd

      Spin = Spin + 0.01!
      Star(i).Angle = Star(i).Angle + (i / %NUMSTARS)
      Star(i).Dist = Star(i).Dist - 0.01!

      IF Star(i).Dist < 0.0! THEN
         star(i).Dist = Star(i).Dist + 5!
         star(i).r = RND(0, 255)
         star(i).g = RND(0, 255)
         star(i).b = RND(0, 255)
      END IF
   NEXT

   ' // Swap buffers
   SDL_GL_SwapBuffers

END SUB
' =======================================================================================

' =======================================================================================
' Main
' =======================================================================================
FUNCTION PBMAIN () AS LONG

   LOCAL pscreen AS SDL_Surface PTR
   LOCAL nWidth, nHeight, bpp AS LONG
   LOCAL lResult, bFullScreen AS LONG
   LOCAL szCaption AS ASCIIZ * 256
   LOCAL dwFlags AS DWORD
   LOCAL t, t0, fps AS DOUBLE
   LOCAL nFrames AS LONG
   LOCAL tp AS LONG

   szCaption = $WindowCaption   ' Window caption

   ' Ask the user which screen mode he prefers
   lResult = MessageBox(%NULL, "Would you like to run in fullscreen mode?", _
             "Start fullScreen?", %MB_YESNOCANCEL OR %MB_ICONQUESTION)
   SELECT CASE lResult
      CASE %IDCANCEL : EXIT FUNCTION
      CASE %IDYES    : bFullScreen = %TRUE
      CASE %IDNO     : bFullScreen = %FALSE
   END SELECT

   ' // Initialize SDL's subsystems - in this case, only video.
   IF SDL_Init(%SDL_INIT_VIDEO) < 0 THEN
      MSGBOX "Unable to init SDL: " & SDL_GetError()
      EXIT FUNCTION
   END IF

   ' // Attempt to create a 640x480 window
   nWidth = 640 : nHeight = 480 : bpp = 16
   IF bFullScreen THEN
      dwFlags = %SDL_OPENGL OR %SDL_FULLSCREEN
   ELSE
      dwFlags = %SDL_OPENGL OR %SDL_RESIZABLE
   END IF
   pscreen = SDL_SetVideoMode(nWidth, nHeight, bpp, dwFlags)
   SDL_WM_SetCaption szCaption, ""

   ' // If we fail, return error.
   IF pscreen = %NULL THEN
      SDL_Quit
      MSGBOX "Unable to set the video mode: " & SDL_GetError()
      EXIT FUNCTION
   END IF

   ' // Set up the scene
   SetupScene

   ' Enable keyboard repeat
   SDL_EnableKeyRepeat %SDL_DEFAULT_REPEAT_DELAY, %SDL_DEFAULT_REPEAT_INTERVAL

   ' // Main loop
   LOCAL done AS LONG
   LOCAL uevent AS SDL_Event
   WHILE done = %FALSE

      ' // Poll for events, and handle the ones we care about.
      WHILE SDL_PollEvent(VARPTR(uevent))
         SELECT CASE uevent.type
            CASE %SDL_KEYDOWN
               SELECT CASE uevent.key.keysym.sym
                  CASE %SDLK_T
                     IF ISFALSE tp THEN
                        tp = %TRUE
                        Twinkle = NOT Twinkle
                     END IF
                  CASE %SDLK_PAGEUP
                     zoom = zoom - 0.02!
                  CASE %SDLK_PAGEDOWN
                     zoom = zoom + 0.02!
                  CASE %SDLK_LEFT
                     Tilt = Tilt - 0.5!
                  CASE %SDLK_RIGHT
                     Tilt = Tilt + 0.5!
               END SELECT
            CASE %SDL_KEYUP
               ' // Quit if escape is pressed
               IF uevent.key.keysym.sym = %SDLK_ESCAPE THEN
                  done = %TRUE
                  EXIT LOOP
               END IF
               ' Reset flag
               tp = %FALSE
            CASE %SDL_VIDEORESIZE
               ' // Change the video mode to the new window size
               nWidth = uevent.resize.w
               nHeight = uevent.resize.h
               pscreen = SDL_SetVideoMode(nWidth, nHeight, bpp, dwFlags)
               IF TextureHandle THEN glDeleteTextures(1, TextureHandle)
               SetupScene
            CASE %SDL_QUIT
               done = %TRUE
               EXIT LOOP
         END SELECT
      WEND

      IF ISFALSE bFullScreen THEN
         ' Get time and mouse position
         t = INT(TIMER)
         ' Calculate and display FPS (frames per second)
         IF t > t0 OR nFrames = 0 THEN
            fps = nFrames \ (t - t0)
            wsprintf szCaption, $WindowCaption & " (%i FPS)", BYVAL fps
            SDL_WM_SetCaption szCaption, szCaption
            t0 = t
            nFrames = 0
         END IF
         nFrames = nFrames + 1
      END IF

      ' // Draw the scene
      DrawScene nWidth, nHeight

   WEND

   ' Delete the texture
   IF TextureHandle THEN glDeleteTextures(1, TextureHandle)

   ' Shut down SDL
   SDL_Quit

END FUNCTION
' =======================================================================================
« Last Edit: August 07, 2011, 08:25:08 PM by José Roca »

Offline José Roca

  • Administrator
  • Hero Member
  • *****
  • Posts: 2481
Re: NeHe Lesson 09: Moving Bitmaps In 3D Space [GLFW Version]
« Reply #2 on: September 16, 2008, 01:16:06 AM »
 
This example illustrates how to move objects around the screen.

It is an adaptation of NeeHe Lesson 09: http://nehe.gamedev.net/data/lessons/lesson.asp?lesson=09

Code: [Select]
' SED_PBWIN - Use the PBWIN compiler
#COMPILE EXE
#DIM ALL
#INCLUDE ONCE "GLFW.INC"
#INCLUDE ONCE "GDIPUTILS.INC"

%NUMSTARS = 50

TYPE Stars
   r     AS LONG
   g     AS LONG
   b     AS LONG
   Dist  AS SINGLE
   Angle AS SINGLE
END TYPE

' =======================================================================================
' Main
' =======================================================================================
FUNCTION PBMAIN () AS LONG

   LOCAL hr, nWidth, nHeight, running, frames AS LONG
   LOCAL x, y, i, Twinkle, tp AS LONG
   LOCAL t, t0, fps AS DOUBLE
   LOCAL szTitlestr AS ASCIIZ * 200
   LOCAL strTextureData AS STRING
   LOCAL TextureWidth, TextureHeight AS LONG
   LOCAL Zoom, Tilt, Spin AS SINGLE
   DIM   glHandle AS DWORD
   DIM   Star(%NUMSTARS) AS Stars

   ' Initialize GLFW
   glfwInit

   ' Open OpenGL window
   IF ISFALSE glfwOpenWindow(640, 480, 0, 0, 0, 0, 16, 0, %GLFW_WINDOW) THEN
      glfwTerminate
      EXIT FUNCTION
   END IF

   ' Load bitmap texture from disk
   hr = GdiPlusLoadTexture("star.bmp", TextureWidth, TextureHeight, strTextureData, %TRUE)

   Zoom = -15!
   Tilt = 90.0!

   ' Assign an OpenGL handle to this texture
   glGenTextures 1, glHandle

   ' Create Linear Filtered Texture
   glBindTexture %GL_TEXTURE_2D, glHandle
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_LINEAR
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_LINEAR
   glTexImage2D %GL_TEXTURE_2D, 0, 3, TextureWidth, TextureHeight, 0, _
                %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Enable texture mapping
   glEnable(%GL_TEXTURE_2D)
   ' Select smooth shading
   glShadeModel %GL_SMOOTH
   ' Specify clear values for the color buffers
   glClearColor 0.0!, 0.0!, 0.0!, 0.0!
   ' Specify the clear value for the depth buffer
   glClearDepth 1.0!

   ' Drop OpenGL hints how to render our graphics
   glHint %GL_POINT_SMOOTH_HINT, %GL_NICEST
   glHint %GL_LINE_SMOOTH_HINT, %GL_NICEST
   glHint %GL_POLYGON_SMOOTH_HINT, %GL_NICEST
   glHint %GL_FOG_HINT, %GL_NICEST
   glHint %GL_PERSPECTIVE_CORRECTION_HINT, %GL_NICEST

   ' Set the blending function for translucency
   glBlendFunc %GL_SRC_ALPHA,%GL_ONE
   glEnable %GL_BLEND

   FOR i = 0 TO %NUMSTARS -1
      Star(i).Angle = 0.0!
      Star(i).Dist = (i / %NUMSTARS) * 5.0! ' Calculate distance from the center
      Star(i).r = RND(0, 255)               ' Give star[loop] a random red intensity
      Star(i).g = RND(0, 255)               ' Give star[loop] a random green intensity
      Star(i).b = RND(0, 255)               ' Give star[loop] a random blue intensity
   NEXT i

   ' Enable sticky keys
   glfwEnable %GLFW_STICKY_KEYS

   ' Disable vertical sync (on cards that support it)
   glfwSwapInterval 0

   ' Main loop
   running = %TRUE
   frames = 0
   t0 = glfwGetTime

   DO WHILE running

      ' Get time and mouse position
      t = glfwGetTime
      glfwGetMousePos x, y
      ' Calculate and display FPS (frames per second)
      IF t - t0 > 1.0! OR frames = 0 THEN
         fps = frames / (t-t0)
         wsprintf szTitlestr, "NEHE Lesson 09 (%i FPS)", BYVAL fps
         glfwSetWindowTitle szTitlestr
         t0 = t
         frames = 0
      END IF
      frames = frames + 1

      '  Get window size (may be different than the requested size)
      glfwGetWindowSize nWidth, nHeight
      IF nHeight <= 0 THEN nHeight = 1

      ' Set viewport
      glViewport 0, 0, nWidth, nHeight

      ' Clear the screen and the depth buffers
      glClear %GL_COLOR_BUFFER_BIT OR %GL_DEPTH_BUFFER_BIT
      ' Select our texture
      glBindTexture %GL_TEXTURE_2D, glHandle

      ' Select and setup the projection matrix
      glMatrixMode %GL_PROJECTION
      glLoadIdentity

      ' Calculate the aspect ratio of the window
      gluPerspective 45.0!, nWidth/nHeight, 0.1!, 100.0!

      ' Select the modelview matrix
      glMatrixMode %GL_MODELVIEW

      FOR i = 0 TO %NUMSTARS - 1
         glLoadIdentity
         glTranslatef 0.0!, 0.0!, Zoom
         glRotatef Tilt, 1.0!, 0.0!, 0.0!

         glRotatef Star(i).Angle, 0.0!, 1.0!, 0.0!
         glTranslatef Star(i).Dist, 0.0!, 0.0!

         glRotatef -Star(i).Angle, 0.0!, 1.0!, 0.0!
         glRotatef -Tilt, 1.0!, 0.0!, 0.0!

         IF Twinkle THEN
            ' Assign a color using bytes
            glColor4ub Star((%NUMSTARS - i) - 1).r, Star((%NUMSTARS - i) - 1).g, Star((%NUMSTARS - i) - 1).b, 255
            glBegin %GL_QUADS
               glTexCoord2f  0.0!,  0.0!: glVertex3f -1.0!, -1.0!,  0.0!
               glTexCoord2f  1.0!,  0.0!: glVertex3f  1.0!, -1.0!,  0.0!
               glTexCoord2f  1.0!,  1.0!: glVertex3f  1.0!,  1.0!,  0.0!
               glTexCoord2f  0.0!,  1.0!: glVertex3f -1.0!,  1.0!,  0.0!
            glEnd
         END IF

         glRotatef Spin, 0.0!, 0.0!, 1.0!

         ' Assign a color using bytes
         glColor4ub Star(i).r, Star(i).g, Star(i).b, 255
         glBegin %GL_QUADS
            glTexCoord2f  0.0!,  0.0!: glVertex3f -1.0!, -1.0!,  0.0!
            glTexCoord2f  1.0!,  0.0!: glVertex3f  1.0!, -1.0!,  0.0!
            glTexCoord2f  1.0!,  1.0!: glVertex3f  1.0!,  1.0!,  0.0!
            glTexCoord2f  0.0!,  1.0!: glVertex3f -1.0!,  1.0!,  0.0!
         glEnd

         Spin = Spin + 0.01!
         Star(i).Angle = Star(i).Angle + (i / %NUMSTARS)
         Star(i).Dist = Star(i).Dist - 0.01!

         IF Star(i).Dist < 0.0! THEN
            star(i).Dist = Star(i).Dist + 5!
            star(i).r = RND(0, 255)
            star(i).g = RND(0, 255)
            star(i).b = RND(0, 255)
         END IF
      NEXT

      ' Swap buffers
      glfwSwapBuffers

      ' T key
      IF glfwGetKey(84) = %GLFW_PRESS AND ISFALSE tp THEN
         tp = %TRUE
         Twinkle = NOT Twinkle
      END IF
      IF glfwGetKey(84) <> %GLFW_PRESS THEN tp = %FALSE

      ' Are any of the arrow keys pressed?
      IF glfwGetKey(%GLFW_KEY_UP) = %GLFW_PRESS THEN Tilt = Tilt - 0.5!
      IF glfwGetKey(%GLFW_KEY_DOWN) = %GLFW_PRESS THEN Tilt = Tilt + 0.5!
      IF glfwGetKey(%GLFW_KEY_PAGEUP) = %GLFW_PRESS THEN Zoom = Zoom - 0.02!
      IF glfwGetKey(%GLFW_KEY_PAGEDOWN) = %GLFW_PRESS THEN Zoom = Zoom + 0.02!

      ' Check if the ESC key was pressed or the window was closed
      running = NOT glfwGetKey(%GLFW_KEY_ESC) AND glfwGetWindowParam(%GLFW_OPENED)

   LOOP

   ' Delete the texture
   IF glHandle THEN glDeleteTextures(1, glHandle)

   ' Close OpenGL window and terminate GLFW
   glfwTerminate

END FUNCTION
' =======================================================================================
« Last Edit: August 07, 2011, 08:53:51 PM by José Roca »